Уважаемые посетители!

Fat-Zer · 06.06.2011 17:04:08

Fat-Zer
Пользователь
Неактивен

Откуда: Москва
Зарегистрирован: 14.10.2010
Сообщений: 4,977
Репутация : [ 256 | 6 ]

Написал свой первый sed скрипт для преобразования из такого:

Autoconf (2.68) - 1,350 KB:
Home page: http://www.gnu.org/software/autoconf/
Download: http://ftp.gnu.org/gnu/autoconf/autoconf-2.68.tar.bz2
MD5 sum: 864d785215aa60d627c91fcb21b05b07
Automake (1.11.1) - 1,042 KB:
Home page: http://www.gnu.org/software/automake/
Download: http://ftp.gnu.org/gnu/automake/automake-1.11.1.tar.bz2
MD5 sum: c2972c4d9b3e29c03d5f2af86249876f

в файл для проверки контрольных сумм:

864d785215aa60d627c91fcb21b05b07  autoconf-2.68.tar.bz2
c2972c4d9b3e29c03d5f2af86249876f  automake-1.11.1.tar.bz2

сам скрипт:

Консоль:

cat src | sed -r '/Download: /!d;s/$/ /;s/.+\///;x;s/.*//;N;s/MD5 sum: //;p;s/.*//;x' | sed -r '/^ *$/d;N;s/\n/ /;s/ +$//' >md5sum

Собственно, критика? Что не так7 что можно сделать проще?

95% процентов проблем находятся между клавиатурой и стулом.

drBatty · 06.06.2011 20:54:30

drBatty
Пользователь
Неактивен

Откуда: Петербург
Зарегистрирован: 20.02.2010
Сообщений: 17,053
Репутация : [ 451 | 73 ]

Fat-Zer пишет:

cat src | sed -r '/Download: /!d;s/$/ /;s/.+\///;x;s/.*//;N;s/MD5 sum: //;p;s/.*//;x' | sed -r '/^ *$/d;N;s/\n/ /;s/ +$//' >md5sum

одностроки - маздай

/Download: /!d
s/$/ /
s/.+\///
x
s/.*//
N;
s/MD5 sum: //
p
s/.*//;
x
' 
| sed -r '
/^ *$/d
N
s/\n/  /
s/ +$//

Карусель разнесло по цепочке за час
Всех известий — конец
Да, весна началась!
(всё к лицу подлецу, как родному отцу, не рассказывай, батя, и так всё пройдёт)

Fat-Zer · 07.06.2011 03:48:34

Fat-Zer
Пользователь
Неактивен

Откуда: Москва
Зарегистрирован: 14.10.2010
Сообщений: 4,977
Репутация : [ 256 | 6 ]

drBatty пишет:

одностроки - маздай

зато когда люди видят такое, то понимают, что ты действительно не из этого мира)).
+писал в командной строке, поэтому разбивать на строки не хотелось...
а кроме того, чтобы записать так, чтобы белые люди это понимали ничего нет? например нерационального использования? лишних команд? и как вообще объеденить это всё в одну команду?

95% процентов проблем находятся между клавиатурой и стулом.

emulek · 07.06.2011 09:45:07

emulek
Новичок
Неактивен

Зарегистрирован: 07.06.2011
Сообщений: 24
Репутация : [ 2 | 0 ]

Fat-Zer пишет:

зато когда люди видят такое, то понимают, что ты действительно не из этого мира)).

ну тема ведь "посмотрите мой скрипт"? смотреть неудобно.

Fat-Zer пишет:

+писал в командной строке, поэтому разбивать на строки не хотелось...

пишите в Vim'е. там и подсветка есть, и вообще... Удобно!

Fat-Zer пишет:

а кроме того, чтобы записать так, чтобы белые люди это понимали ничего нет? например нерационального использования? лишних команд?

дело в том, что разбивать команды вы можете как угодно, по синтаксису sed всё едино - точка с запятой или перевод строки.
Однако, есть множество команд (a,i,c,w,W,r,R и ещё какие-то), где параметр "до конца строки". Вам придётся писать так:

sed -e 'a какой-то текст' -e 'a ещё текст' -e 'w имя файла'

Fat-Zer пишет:

как вообще объеденить это всё в одну команду?

зачем?
можно конечно. только, напишите по-русски, ЧТО этот скрипт делает (можно только для себя).
Hint: в sed есть блоки как в C:

/условие/{
 # какие-то команды по условию
}
# безусловные команды

Кстати, используемая вами d это тоже на самом деле команда условного перехода.

/условие/d
# здесь команды, которые выполняются если невыполнено условие

Fat-Zer · 07.06.2011 13:05:20

Fat-Zer
Пользователь
Неактивен

Откуда: Москва
Зарегистрирован: 14.10.2010
Сообщений: 4,977
Репутация : [ 256 | 6 ]

emulek пишет:

можно конечно. только, напишите по-русски, ЧТО этот скрипт делает (можно только для себя).

в первом посте есть пример исходных данных и результата. надо выдрать имя скачанного файла и контрольную сумму. и записать их красиво для "md5sum -c"

95% процентов проблем находятся между клавиатурой и стулом.

drBatty · 10.06.2011 12:27:55

drBatty
Пользователь
Неактивен

Откуда: Петербург
Зарегистрирован: 20.02.2010
Сообщений: 17,053
Репутация : [ 451 | 73 ]

Fat-Zer пишет:

надо выдрать имя скачанного файла и контрольную сумму. и записать их красиво

ну вот как-то так:

#!/bin/sed -rnf

/^Download:\s+/{
    s~.*/~~
    h
}

/^MD5 sum:\s+/{
    s///
    H
    g
    s/.+\n/ /p
    z
    h
}

согласитесь - всё намного понятнее?

//fixed
дополнительная фича - если ссылки не было, то вообще ничего не напечатает.

Карусель разнесло по цепочке за час
Всех известий — конец
Да, весна началась!
(всё к лицу подлецу, как родному отцу, не рассказывай, батя, и так всё пройдёт)

Fat-Zer · 11.06.2011 13:08:11

Fat-Zer
Пользователь
Неактивен

Откуда: Москва
Зарегистрирован: 14.10.2010
Сообщений: 4,977
Репутация : [ 256 | 6 ]

растолкуйте, что делает "s~.*/~~"

ЗЫ: про комманды g и h не знал... поэтому всё так и получилось громостко и запутано...

95% процентов проблем находятся между клавиатурой и стулом.

drBatty · 11.06.2011 13:43:42

drBatty
Пользователь
Неактивен

Откуда: Петербург
Зарегистрирован: 20.02.2010
Сообщений: 17,053
Репутация : [ 451 | 73 ]

Fat-Zer пишет:

растолкуйте, что делает "s~.*/~~" и "s///"
ЗЫ: про комманды g и h не знал... поэтому всё так и получилось громостко и запутано...

http://drbatty.ru/sed (Сегодня с 6:00 до 14:00 по московскому времени проводятся плановые работы)

s~.*/~~ заменяет любые символы в любом количестве (да побольше!) за которыми идёт слеш на "".
например "Download: http://ftp.gnu.org/gnu/autoconf/autoconf-2.68.tar.bz2" заменится на "autoconf-2.68.tar.bz2"

s/// это команда, которая заменяет регулярку на "".

регулярное выражение == компилируемая программа. И её можно использовать много раз.

/ABC/p # ищем строку с ABC и её печатаем
s//DEF/g # заменяем ранее скомпилированое выражение (ABC) на DEF. Причём, в первый раз найдётся лишь первое совпадение, а в этот раз - все ABC заменяются на DEF.

Карусель разнесло по цепочке за час
Всех известий — конец
Да, весна началась!
(всё к лицу подлецу, как родному отцу, не рассказывай, батя, и так всё пройдёт)

Fat-Zer · 11.06.2011 14:55:03

Fat-Zer
Пользователь
Неактивен

Откуда: Москва
Зарегистрирован: 14.10.2010
Сообщений: 4,977
Репутация : [ 256 | 6 ]

// fixed

#!/bin/sed -rnf

/^Download:\s+/{
    s~.*/~~
    h
}

/^MD5 sum:\s+/{
    s///
    G
    s/\n/ /
    p
}

drBatty пишет:

s~.*/~~ заменяет любые символы в любом количестве (да побольше!) за которыми идёт слеш на "".

не могу найти, где такой синтаксис s описан...

ЗЫ: уже почти 3, а сервис до сих пор лежит...

95% процентов проблем находятся между клавиатурой и стулом.

drBatty · 11.06.2011 17:06:15

drBatty
Пользователь
Неактивен

Откуда: Петербург
Зарегистрирован: 20.02.2010
Сообщений: 17,053
Репутация : [ 451 | 73 ]

Fat-Zer пишет:

не могу найти, где такой синтаксис s описан...
ЗЫ: уже почти 3, а сервис до сих пор лежит...

заработал сервер.

обычно пишут s/abc/def/, но вместо слеша можно использовать любой символ, например s~abc~drf~ это тоже самое.

ненавижу заборы http:\/\/drbatty\.ru\/sed

Карусель разнесло по цепочке за час
Всех известий — конец
Да, весна началась!
(всё к лицу подлецу, как родному отцу, не рассказывай, батя, и так всё пройдёт)

Уважаемые посетители!

посмотрите мой sed скрипт.

Сообщений 10

1 Тема от Fat-Zer 06.06.2011 17:04:08 (07.06.2011 11:20:19 отредактировано Fat-Zer)

2 Ответ от drBatty 06.06.2011 20:54:30

3 Ответ от Fat-Zer 07.06.2011 03:48:34

4 Ответ от emulek 07.06.2011 09:45:07

5 Ответ от Fat-Zer 07.06.2011 13:05:20

6 Ответ от drBatty 10.06.2011 12:27:55 (10.06.2011 12:33:34 отредактировано drBatty)

7 Ответ от Fat-Zer 11.06.2011 13:08:11 (11.06.2011 13:27:33 отредактировано Fat-Zer)

8 Ответ от drBatty 11.06.2011 13:43:42

9 Ответ от Fat-Zer 11.06.2011 14:55:03

10 Ответ от drBatty 11.06.2011 17:06:15

Сообщений 10

Просматривают тему: 1 гость, 0 пользователей